You can actually use straight examples of Tcl client/server communication on IOS with a few minor mods. Take a look at
http://www.tcl.tk/about/netserver.html . What you would need to do is wrap these scripts in EEM syntax. For example, on the server side:
::cisco::eem::event_register_none
namespace import ::cisco::eem::*
namespace import ::cisco::lib::*
array set arr_einfo [event_reqinfo]
# Echo_Server --
# Open the server listening socket
# and enter the Tcl event loop
#
# Arguments:
# port The server's port number
proc Echo_Server {port} {
set s [socket -server EchoAccept $port]
vwait forever
}
# Echo_Accept --
# Accept a connection from a new client.
# This is called after a new socket connection
# has been created by Tcl.
#
# Arguments:
# sock The new socket connection to the client
# addr The client's IP address
# port The client's port number
proc EchoAccept {sock addr port} {
global echo
# Record the client's information
puts "Accept $sock from $addr port $port"
set echo(addr,$sock) [list $addr $port]
# Ensure that each "puts" by the server
# results in a network transmission
fconfigure $sock -buffering line
# Set up a callback for when the client sends data
fileevent $sock readable [list Echo $sock]
}
# Echo --
# This procedure is called when the server
# can read data from the client
#
# Arguments:
# sock The socket connection to the client
proc Echo {sock} {
global echo
# Check end of file or abnormal connection drop,
# then echo data back to the client.
if {[eof $sock] || [catch {gets $sock line}]} {
close $sock
puts "Close $echo(addr,$sock)"
unset echo(addr,$sock)
} else {
puts $sock $line
}
}
Echo_Server $arr_einfo(arg1)
Register this as an EEM Tcl policy (assuming this script lives in flash:/policies as no_echo_server.tcl on the device):
event manager directory user policy flash:/policies
event manager policy no_echo_server.tcl
Then run it from EXEC mode:
event manager run no_echo_server.tcl 3333
That will start a listening socket on tcp/3333 on this device.
On the client device, create a script called no_echo_client.tcl with:
::cisco::eem::event_register_none
namespace import ::cisco::eem::*
namespace import ::cisco::lib::*
array set arr_einfo [event_reqinfo]
#
# A client of the echo service.
#
proc Echo_Client {host port} {
set s [socket $host $port]
fconfigure $s -buffering line
return $s
}
set sock [Echo_Client $arr_einfo(arg1) $arr_einfo(arg2)]
puts $sock "Hello!"
gets $sock response
puts "Response is $response"
Again, register this policy, then run it from EXEC mode with:
event manager run no_echo_client.tcl 10.1.1.1 3333
Where 10.1.1.1 is the IP address of the first (i.e., server) device.
That's it. That's a simple client/server example on IOS with EEM.
